Trainer

[HealingOne]

is there any way to remove a trainer from sz without rebootin the server?

 

[Geordiehc]

is there any way to remove a trainer from sz without rebootin the server?

Well even if you change its race it wouldn't effect it because the mob needs to respawn first so in essence its a NPC and therefore can't be removed until you reboot.

 

[HealingOne]

thanks for reply

 

[Amenovis]

mhh how is it if u press the npc reload button on the cd.exe as i know there is a button for npv reload

 

[Inflikted]

i highly doubt this will work lol and i havent tried it.. but have you tried to create an
npcmove script? it works for normal NPC's, so you can move around NPC's while the server is live.. maybe works for trainers too.

 

[Geordiehc]

i highly doubt this will work lol and i havent tried it.. but have you tried to create an
npcmove script? it works for normal NPC's, so you can move around NPC's while the server is live.. maybe works for trainers too.

Isn't it a mob?

 

[chimera]

If like me you've got an npc on a gm only map you can use to test scripts just do a little script to move an npc to an unused map or do a monclear script specifying a name.

 

[idaBigA]

I have my Admin Menu on the D Button

Here is the Map Mob Clear script I use

[@ClearMapMobs1]
#ACT
Mov  A0  %USERMAP
Mov  A1  "*"
Goto @ClearMapMobs

[@ClearMapMobs]
#SAY
This will clear Mobs from a Map\
Please Choose which Mob and what Map\
If you Enter a "*" into the Mob Field it will\
Clear All Mobs\\
{FCOLOR/10}Map : {FCOLOR/1}<$OUTPUT(A0)>\
{FCOLOR/10}Mob : {FCOLOR/1}<$OUTPUT(A1)>\\
<[ Enter Map Name ]/@@ChangeMap>\

<[ Enter Mob Name ]/@@ChangeMob>\

<[ Clear Selected Mob ]/@ClearMapMobs3>\\
<[ Back ]/@AdminScript>

[@@ChangeMap]
#ACT
Mov    A0   %INPUTSTR
goto @ClearMapMobs

[@@ChangeMob]
#ACT
Mov    A1   %INPUTSTR
goto @ClearMapMobs

[@ClearMapMobs3]
#SAY
Are you Sure?\\
<[ Yes ]/@ClearMapMobs2>\
<[ Back ]/@AdminScript>

[@ClearMapMobs2]
#IF
EQUAL  A1  "*"
#ACT
MonClear  %A0 
#SAY
Mob : {FCOLOR/10}All{FCOLOR/12} cleared from Map : {FCOLOR/10}<$OUTPUT(A0)>{FCOLOR/12}\
<[ Back ]/@AdminScript>
#IF
!EQUAL A1  "*"
#ACT
MonClear  %A0  %A1
#SAY
Mob : {FCOLOR/10}<$OUTPUT(A1)> {FCOLOR/12}Cleared from Map : {FCOLOR/10}<$OUTPUT(A0)>{FCOLOR/12}\
<[ Back ]/@AdminScript>

 

[mirlin6]

can you move npc while server is live?

 

[idaBigA]

Yeah, use the MoveNPC command.

MoveNPC "MapFrom,XFrom,YFrom,NPC's_FullName" MapTo XTo YTo

This will move the NPC from one map X and Y to another Map X and Y..

i.e.

MoveNPC "10,450,467,QuestNPC" 5 100 120

This will move the NPC with name "QuestNPC" from Map 10, Co-ords 450,467 to Map 5, Co-ords 100,120

 

[mirlin6]

is there a way i could respwan mobs like the script you posted above Idabiga?

also could i please use the clear bag script please sometime my bag gets full :P

 

[idaBigA]

#IF
!CheckMapMob Monkey 1
#ACT
SpawnMob Monkey 1

Not the commands, but easy enough to do..

The Clear Bag script is just a big list of all my items..

#ACT
Take HPPotion(M) 1000
Take CopperRing 1000
Take WoodenSword 1000
ETC
ETC
ETC

Huge List.. and it also doesn't take Stacked Pots..

 

[mirlin6]

ive figured a way to do it but how would i make it so i input say 11 as a respawn location and it reads that in the script then goes to that part of script

But how would it read what i input

 

[idaBigA]

Inputs are covered in numerous locations.. including the above example I put up..

[@Main]
#IF
#SAY
<[ Enter Mob Name ]/@@ChangeMob>\   ;Notice the 2 @@ Symbols

[@@ChangeMob]                       ;Notice the 2 @@ Symbols
#ACT
Mov    A1   %INPUTSTR               ;This brings up an Input Box
#SAY
<$OUTPUT(A1)> A1 Contains what you have just written!\\

#IF
Equal  A1  "11"
#ACT
Goto @Part11

#IF
Equal  A1  "12"
#ACT
Goto @Part12

 

[mirlin6]

whats command to spawn a mob ive tried MONGEN?

 

[idaBigA]

No offense Mirlin, but all of this info is easily found in the standard files you get. Simply search for MonGen and it will show you how to do these things.

[@main]
#ACT
MonGenP "10,354,237,0" Guard 1

To turn this into a more useful tool.. add this command in with the other commands above..

[@SpawnSelection]
#ACT
Mov A1  %USERMAP
Mov D1  %USERX
Mov D2  %USERY
Mov D3  50
Mov D4  1
Mov A2  "Hen"
#SAY
Map - {FCOLOR/1}<$OUTPUT(A1)>{FCOLOR/10}\
X - {FCOLOR/1}<$OUTPUT(D1)>{FCOLOR/10}\
Y - {FCOLOR/1}<$OUTPUT(D2)>{FCOLOR/10}\
Rad - {FCOLOR/1}<$OUTPUT(D3)>{FCOLOR/10}\
Qty - {FCOLOR/1}<$OUTPUT(D4)>{FCOLOR/10}\
Mob - {FCOLOR/1}<$OUTPUT(A2)>{FCOLOR/10}\\
<[ Select Map ]/@@SelectMap>\
<[ Select X ]/@@SelectX>\
<[ Select Y ]/@@SelectY>\
<[ Select Radius ]/@@SelectRad>\
<[ Select Qty ]/@@SelectQty>\
<[ Select Mob ]/@@SelectMob>\\
<[ Spawn ]/@SpawnMobs>\\\

[@@SelectMap]
#ACT
Mov A1 %INPUTSTR
Goto @SpawnSelection

[@@SelectX]
#ACT
Mov D1 %INPUTSTR
Goto @SpawnSelection

[@@SelectY]
#ACT
Mov D2 %INPUTSTR
Goto @SpawnSelection

[@@SelectRad]
#ACT
Mov D3 %INPUTSTR
Goto @SpawnSelection

[@@SelectQty]
#ACT
Mov D4 %INPUTSTR
Goto @SpawnSelection

[@@SelectMob]
#ACT
Mov A2 %INPUTSTR
Goto @SpawnSelection

[@SpawnMobs]
#ACT
FormatStr "%s,%s,%s" %A1 %D1 %D2
Mov   A0  %A9
FormatStr "%s,%s" %A0 %D3
Mov   A8  %A9"
MonGenP %A8 %A2 %D4

That should work (more or less), I haven't tested, but it shouldn't be far wrong..

Seriously though, that script took me no time to write and that included having a search through the files to get the correct syntax for the commands, have a search through your files, its suprising what you will find and learn.

One final note, its easier (if you are online) to just use GM commands for spawning mobs :P

 

[mirlin6]

sorry im a pain lol i will search and see what i find